/* OpenIntro LAB 8   */

*Read in the data from the CSV file located on the OpenIntro website;
filename evals url 
         'http://www.openintro.org/stat/data/evals_sas.csv';

proc import datafile=evals
            out=evals
            dbms=csv
            replace; 
   getnames=yes;
run;

*Scatter plot of score and bty_avg;
proc sgplot data=evals;
   scatter y=score x=bty_avg;
run;

*Calculate the correlation for bty_avg and bty_f1lower, and generate the scatterplot;
proc corr data=evals plots=scatter(ellipse=none);
   var bty_avg bty_f1lower;
run;

*Generate scatterplots for bty_f1lower through bty_avg;
ods select matrixplot;
proc corr data=evals plots(maxpoints=20000)=matrix(nvar=7);
   var bty_f1lower--bty_avg;
run;

*Perform a regression of score on bty_avg and gender;
proc glm data=evals;
   class gender / ref=first;
   model score=bty_avg gender / solution;
run;
quit;

*Perform a regression predicting score from 13 predictors;
proc glm data=evals;
   class rank ethnicity gender language cls_level cls_profs
         cls_credits pic_outfit pic_color / ref=first;
   model score=rank ethnicity gender language age cls_perc_eval 
         cls_students cls_level cls_profs cls_credits bty_avg 
         pic_outfit pic_color / solution;
run;
quit;